unit MainFrm;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics,
  Controls, Forms, Dialogs, ShellAPI, Menus;

const
  WM_TRAYICON = WM_USER+1;

type
  TMainForm = class(TForm)
    TrayMenu: TPopupMenu;
    miClose: TMenuItem;
    procedure FormPaint(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure miCloseClick(Sender: TObject);
  private
    Starting: Boolean;
    NIData: TNotifyIconData;
  public
    procedure IconCallBackMessage(var Msg: TMessage); message WM_TRAYICON;
  end;

var
  MainForm: TMainForm;

implementation

{$R *.DFM}

procedure TMainForm.FormPaint(Sender: TObject);
begin
 if Starting then begin
  Starting:=False;
  ShowWindow(Application.Handle, SW_HIDE);
 end;
end;

procedure TMainForm.FormCreate(Sender: TObject);
begin
 Starting:=True;
 with NIData do begin
  cbSize:=sizeof(NIData);
  Wnd:=Self.handle;
  uID:=1;
  uFlags:=NIF_ICON or NIF_TIP or NIF_MESSAGE;
  hIcon:=Application.Icon.Handle;
  szTip:='Ohjelman nimi';
  uCallBackMessage:=WM_TRAYICON;
 end;
 Shell_NotifyIcon(NIM_ADD,@NIData);
end;

procedure TMainForm.IconCallBackMessage(var Msg: TMessage);
var MousePos: Tpoint;
begin
 case Msg.lParam of
  WM_LBUTTONDOWN: SetForegroundWindow(Application.Handle);
  WM_RBUTTONDOWN: begin
   GetCursorPos(MousePos);
   SetForegroundWindow(Application.Handle);
   Application.ProcessMessages;
   TrayMenu.Popup(MousePos.X,MousePos.Y);
  end;
 end;
end;

procedure TMainForm.FormDestroy(Sender: TObject);
begin
 Shell_NotifyIcon(NIM_DELETE,@NIData);
end;

procedure TMainForm.miCloseClick(Sender: TObject);
begin
 Close;
end;

end.